C++ port

Signed-off-by: Juan Cruz Viotti <jv@jviotti.com>

Author: jviotti

cmake/Findmpdecimal.cmake

@@ -83,8 +83,7 @@ if(NOT mpdecimal_FOUND)
     if(BUILD_SHARED_LIBS)
       target_compile_definitions(mpdecimal PRIVATE BUILD_LIBMPDEC)
     else()
-      set_target_properties(mpdecimal PROPERTIES
-        MSVC_RUNTIME_LIBRARY "MultiThreaded$<$<CONFIG:Debug>:Debug>")
+      target_compile_options(mpdecimal PRIVATE /U_DLL)
     endif()
   endif()
 
@@ -98,6 +97,48 @@ if(NOT mpdecimal_FOUND)
       C_VISIBILITY_INLINES_HIDDEN FALSE
       EXPORT_NAME mpdecimal)
 
+  set(MPDECIMALXX_DIR "${MPDECIMAL_DIR}/libmpdec++")
+  set(MPDECIMALXX_PUBLIC_HEADER "${MPDECIMALXX_DIR}/decimal.hh")
+  set(MPDECIMALXX_SOURCES "${MPDECIMALXX_DIR}/decimal.cc")
+
+  add_library(mpdecimalxx ${MPDECIMALXX_SOURCES})
+
+  target_include_directories(mpdecimalxx PRIVATE
+    "${MPDECIMALXX_DIR}"
+    "${MPDECIMAL_SOURCE_DIR}")
+
+  target_include_directories(mpdecimalxx PUBLIC
+    "$<BUILD_INTERFACE:${MPDECIMALXX_DIR}>"
+    "$<INSTALL_INTERFACE:${CMAKE_INSTALL_INCLUDEDIR}>")
+
+  target_link_libraries(mpdecimalxx PUBLIC mpdecimal)
+
+  if(UNIX)
+    find_package(Threads REQUIRED)
+    target_link_libraries(mpdecimalxx PRIVATE Threads::Threads)
+    if(NOT APPLE)
+      target_link_libraries(mpdecimalxx PRIVATE m)
+    endif()
+  endif()
+
+  if(MSVC)
+    if(BUILD_SHARED_LIBS)
+      target_compile_definitions(mpdecimalxx PRIVATE BUILD_LIBMPDECXX)
+    else()
+      target_compile_options(mpdecimalxx PRIVATE /U_DLL)
+    endif()
+  endif()
+
+  add_library(mpdecimal::mpdecimalxx ALIAS mpdecimalxx)
+
+  set_target_properties(mpdecimalxx
+    PROPERTIES
+      OUTPUT_NAME mpdecimalxx
+      PUBLIC_HEADER "${MPDECIMALXX_PUBLIC_HEADER}"
+      CXX_VISIBILITY_PRESET "default"
+      VISIBILITY_INLINES_HIDDEN FALSE
+      EXPORT_NAME mpdecimalxx)
+
   if(SOURCEMETA_CORE_INSTALL)
     include(GNUInstallDirs)
     install(TARGETS mpdecimal
@@ -123,6 +164,35 @@ if(NOT mpdecimal_FOUND)
       "${CMAKE_CURRENT_BINARY_DIR}/mpdecimal-config.cmake"
       DESTINATION "${CMAKE_INSTALL_LIBDIR}/cmake/mpdecimal"
       COMPONENT sourcemeta_core_dev)
+
+    install(TARGETS mpdecimalxx
+      EXPORT mpdecimalxx
+      PUBLIC_HEADER DESTINATION "${CMAKE_INSTALL_INCLUDEDIR}"
+        COMPONENT sourcemeta_core_dev
+      RUNTIME DESTINATION "${CMAKE_INSTALL_BINDIR}"
+        COMPONENT sourcemeta_core
+      LIBRARY DESTINATION "${CMAKE_INSTALL_LIBDIR}"
+        COMPONENT sourcemeta_core
+        NAMELINK_COMPONENT sourcemeta_core_dev
+      ARCHIVE DESTINATION "${CMAKE_INSTALL_LIBDIR}"
+        COMPONENT sourcemeta_core_dev)
+    install(EXPORT mpdecimalxx
+      DESTINATION "${CMAKE_INSTALL_LIBDIR}/cmake/mpdecimalxx"
+      NAMESPACE mpdecimal::
+      COMPONENT sourcemeta_core_dev)
+
+    file(WRITE ${CMAKE_CURRENT_BINARY_DIR}/mpdecimalxx-config.cmake
+      "include(CMakeFindDependencyMacro)\n"
+      "find_dependency(mpdecimal CONFIG)\n"
+      "if(UNIX)\n"
+      "  find_dependency(Threads)\n"
+      "endif()\n"
+      "include(\"\${CMAKE_CURRENT_LIST_DIR}/mpdecimalxx.cmake\")\n"
+      "check_required_components(\"mpdecimalxx\")\n")
+    install(FILES
+      "${CMAKE_CURRENT_BINARY_DIR}/mpdecimalxx-config.cmake"
+      DESTINATION "${CMAKE_INSTALL_LIBDIR}/cmake/mpdecimalxx"
+      COMPONENT sourcemeta_core_dev)
   endif()
 
   set(mpdecimal_FOUND ON)

config.cmake.in

@@ -48,6 +48,7 @@ foreach(component ${SOURCEMETA_CORE_COMPONENTS})
   elseif(component STREQUAL "json")
     include("${CMAKE_CURRENT_LIST_DIR}/sourcemeta_core_io.cmake")
     find_dependency(mpdecimal CONFIG)
+    find_dependency(mpdecimalxx CONFIG)
     include("${CMAKE_CURRENT_LIST_DIR}/sourcemeta_core_json.cmake")
   elseif(component STREQUAL "jsonl")
     include("${CMAKE_CURRENT_LIST_DIR}/sourcemeta_core_json.cmake")

src/core/json/CMakeLists.txt

@@ -8,3 +8,4 @@ endif()
 
 target_link_libraries(sourcemeta_core_json PRIVATE sourcemeta::core::io)
 target_link_libraries(sourcemeta_core_json PRIVATE mpdecimal)
+target_link_libraries(sourcemeta_core_json PRIVATE mpdecimalxx)

vendor-mpdecimal.sh

@@ -25,7 +25,14 @@ rm -rf "$DIRECTORY/libmpdec/literature"
 rm -rf "$DIRECTORY/libmpdec/Makefile.in"
 rm -rf "$DIRECTORY/libmpdec/Makefile.vc"
 rm -rf "$DIRECTORY/libmpdec/README.txt"
-rm -rf "$DIRECTORY/libmpdec++"
+rm -rf "$DIRECTORY/libmpdec++/.objs"
+rm -rf "$DIRECTORY/libmpdec++/.pc"
+rm -rf "$DIRECTORY/libmpdec++/.profile"
+rm -rf "$DIRECTORY/libmpdec++/examples"
+rm -rf "$DIRECTORY/libmpdec++/bench.cc"
+rm -rf "$DIRECTORY/libmpdec++/bench_full.cc"
+rm -rf "$DIRECTORY/libmpdec++/Makefile.in"
+rm -rf "$DIRECTORY/libmpdec++/Makefile.vc"
 rm -rf "$DIRECTORY/tests"
 rm -rf "$DIRECTORY/tests++"
 rm -rf "$DIRECTORY/vcbuild"