3834 Extend cider-map-repls to allow ensured op list

Author: wilbrt

cider-connection.el

@@ -1053,8 +1053,9 @@ throw an error if no linked session exists."
 (defun cider-map-repls (which function)
   "Call FUNCTION once for each appropriate REPL as indicated by WHICH.
 The function is called with one argument, the REPL buffer.  The appropriate
-connections are found by inspecting the current buffer.  WHICH is one of
-the following keywords:
+connections are found by inspecting the current buffer.  WHICH is either one of
+the following keywords or a list starting with one of them followed by names of
+operations that the REPL is expected to support:
  :auto - Act on the connections whose type matches the current buffer.  In
      `cljc' files, mapping happens over both types of REPLs.
  :clj (:cljs) - Map over clj (cljs)) REPLs only.
@@ -1064,23 +1065,33 @@ the following keywords:
 Error is signaled if no REPL buffers of specified type exist in current
 session."
   (declare (indent 1))
-  (let ((cur-type (cider-repl-type-for-buffer)))
-    (cl-case which
+  (let ((cur-type (cider-repl-type-for-buffer))
+        (which-key (or (car-safe which) which))
+        (ops-to-support (cdr-safe which)))
+    (cl-case which-key
       (:clj-strict (when (eq cur-type 'cljs)
                      (user-error "Clojure-only operation requested in a ClojureScript buffer")))
       (:cljs-strict (when (eq cur-type 'clj)
                       (user-error "ClojureScript-only operation requested in a Clojure buffer"))))
-    (let* ((type (cl-case which
+    (let* ((type (cl-case which-key
                    ((:clj :clj-strict) 'clj)
                    ((:cljs :cljs-strict) 'cljs)
                    (:auto (if (eq cur-type 'multi)
                               '(clj cljs)
                             cur-type))))
-           (ensure (cl-case which
+           (ensure (cl-case which-key
                      (:auto nil)
                      (t 'ensure)))
            (repls (cider-repls type ensure)))
-      (mapcar function repls))))
+      (mapcar (lambda (repl)
+                (mapc (lambda (op)
+                        (unless (nrepl-op-supported-p op repl)
+                          (user-error "`%s' requires the nREPL op \"%s\" (provided by cider-nrepl)"
+                                      this-command op)))
+                      ops-to-support)
+                (funcall function repl))
+              repls))))
+
 
 ;; REPLs double as connections in CIDER, so it's useful to be able to refer to
 ;; them as connections in certain contexts.

cider-ns.el

@@ -300,10 +300,8 @@ refresh functions (defined in `cider-ns-refresh-before-fn' and
   (let ((clear? (member mode '(clear 16)))
         (all? (member mode '(refresh-all 4)))
         (inhibit-refresh-fns (member mode '(inhibit-fns -1))))
-    (cider-map-repls :clj
+    (cider-map-repls '(:clj "refresh" "cider.clj-reload/reload")
       (lambda (conn)
-        (cider-ensure-op-supported "refresh" conn)
-        (cider-ensure-op-supported "cider.clj-reload/reload" conn)
         (cider-ns-refresh--save-modified-buffers conn)
         ;; Inside the lambda, so the buffer is not created if we error out.
         (let ((log-buffer (or (get-buffer cider-ns-refresh-log-buffer)